D365 Finance and Operations. Get path for the menu item via code.

In one of my previous posts, I have shared an idea of how a new Dynamics 365 SCM and Finance API can be used to get metadata of Dynamics 365 AOT elements. 

Learning a path to a menu item from a user interface perspective could come in handy.

So I have created the method that I would like to share:

public static str getMenuItemPath(str _menuItemName)

{

   MenuFunction mf = new MenuFunction(_menuItemName, MenuItemType::Display);

   str          menuLabel;

   str          ret;

   boolean iterateMenus(SysDictMenu _menu)

   {

      SysMenuEnumerator       menuEnum = _menu.getEnumerator();

      SysDictMenu             subMenu;

      boolean                 found;

      while (menuEnum.moveNext())

      {

         subMenu = menuEnum.current();

         if (subMenu.isMenu() || subMenu.isMenuReference())

         {

            found = iterateMenus(subMenu);

            if (found) // If found, just climb back up the stack

            {

               menuLabel = strFmt('%1/%2', subMenu.label(), menuLabel);

               return found;

            }

         }

         else

         {

            if (subMenu.isMenuItem()

             && subMenu.isValid()

             && subMenu.isVisible()

             && subMenu.menuItem().name() == mf.name()

             && subMenu.menuItem().type() == mf.type())

            {

               menuLabel = subMenu.label();

               return true;

            }

         }

      }

      return false;

   }

   If (iterateMenus(SysDictMenu::newMainMenu()))

   {

      ret = strfmt('%1', menuLabel);

   }

   return ret;

}

You can find a couple of examples of using the method presented above, below :

1. info(strFmt('%1', Class::getMenuItemPath('SalesTableListPage')));

It will return the result: Accounts receivable/Orders/All sales orders

2. info(strFmt('%1', Class::getMenuItemPath(menuItemDisplayStr(InventLocations))));

It will return the result: Inventory management/Setup/Inventory breakdown/Warehouses